% ====================================================
% ogni atomo ha tutte variabili distinte nel body. Nella testa non necessariamente.
:- pred constr(bool). 
:- mode constr(in). 
:- ignore constr/1.

% ====================================================
% Program. mergesorting in ascending order.E.g., 3 =< 5 =< 5 =< 8 =< ...
:- pred mergesort(list(int),list(int)).
:- mode mergesort(in,out).
mergesort([], []).
mergesort([H], [H]).
mergesort([H,K|T],S) :-
   cons(K,T,KT),          
   cons(H,KT,HKT),          
   split(HKT,L1,L2),       
   mergesort(L1,S1),       
   mergesort(L2,S2),
   merge(S1,S2,S).         % merging

:- pred cons(int,list(int),list(int)).
:- mode cons(in,in,out).
cons(H,T,[H|T]).

:- pred split(list(int),list(int),list(int)).
:- mode split(in,out,out).
split(L,L1,L2) :- N1=(N div 2),      % integer division is div in SMTLIB.
     length(L,N),                    
     takedrop(N1,L,L1,L2).

:- pred length(list(int),int).
:- mode length(in,out).
length([],L) :- constr(L=0).
length([H|T],L) :-
  constr( L=(LT+1) ),
  length(T,LT).

:- pred takedrop(int,list(int),list(int),list(int)).
:- mode takedrop(in,in,out,out).
takedrop(N,[],[],[]).
takedrop(N,L,[],L) :- N=<0.
takedrop(N,[H|T],[H|T1],L) :- 
  N>=1, N1=(N-1),  
  takedrop(N1,T,T1,L).

:- pred merge(list(int),list(int),list(int)).
:- mode merge(in,in,out).
merge([],L,L).                 
merge([X|Xs],[],[X|Xs]).
merge([X|Xs],[Y|Ys],[X|Zs]) :-
     constr(X=<Y), cons(Y,Ys,YYs),
     merge(Xs,YYs,Zs).
merge([X|Xs],[Y|Ys],[Y|Zs]) :-
     constr(X>Y), cons(X,Xs,XXs),
     merge(XXs,Ys,Zs).
     
% ====================================================
% catamorphism
% 
:- pred lengthcata(list(int),int).
:- mode lengthcata(in,out).
:- cata lengthcata/2-1.

lengthcata([],L) :- L=0.
lengthcata([H|T],L) :-
  L=(LT+1),
  lengthcata(T,LT). 
  
% ====================================================
% verification. 
% Property:
:- pred ff1.
ff1 :-                               % mergesort
   constr( ~(CL=CS)), 
   lengthcata(L,CL), lengthcata(S,CS),  
   mergesort(L,S).

:- pred ff2.
ff2 :-                               % split
   constr( ~(NXs = (NYs+NZs)) ),
   lengthcata(Xs,NXs), lengthcata(Ys,NYs), lengthcata(Zs,NZs),
   split(Xs,Ys,Zs).

:- pred ff3.                        % merge
ff3 :- 
   constr( ~(NZs = (NXs+NYs)) ),
   lengthcata(Xs,NXs), lengthcata(Ys,NYs), lengthcata(Zs,NZs),
   merge(Xs,Ys,Zs).
   
:- pred ff4.
ff4 :-                              % takedrop
   constr( ~(LLs = (LTs+LDs))),
   lengthcata(Ls,LLs), lengthcata(Ts,LTs), lengthcata(Ds,LDs),
   takedrop(N,Ls,Ts,Ds). 

:- pred ff5.
ff5 :-                              % cons
    constr( ~(NXHT = NXT+1) ),
    lengthcata(T,NXT), lengthcata(HT,NXHT),
    cons(H,T,HT).
% ================================================================= 
:- query ff1/0.
:- query ff2/0.
:- query ff3/0.
:- query ff4/0.
:- query ff5/0.
% =================================================================