% =================================================================
:- pred constr(bool).    
:- mode constr(in).
:- ignore constr/1.

% =================================================================
% Program
:- pred quicksort(list(int),list(int)).
:- mode quicksort(in,out).
quicksort([], []).
quicksort([X | Xs], ResL) :-
	partition(X, Xs, Smalls, Bigs),   % partition of the tail Xs 
	quicksort(Smalls, Ls),            % with respect to the pivot X.
	quicksort(Bigs, Bs),              % X is NOT in Xs.
  cons(X,Bs,XBs),
	append(Ls, XBs, ResL).

:- pred partition(int,list(int),list(int),list(int)).
:- mode partition(in,in,out,out).
partition(X, [], [], []).
partition(X, [Y | Ys], [Y | Ls], Bs) :- 
      	constr( (X>Y) ),    
      	partition(X, Ys, Ls, Bs).
partition(X, [Y | Xs], Ls, [Y | Bs]) :-  
				constr( (X=<Y)  ),   
  			partition(X, Xs, Ls, Ls1). %error: (X, Xs, Ls, Ls1) ---> (X, Xs, Ls, Bs)

:- pred append(list(int),list(int),list(int)).
:- mode append(in,in,out).
append([],Ys,Ys).
append([X|Xs],Ys,[X|Zs]) :- append(Xs,Ys,Zs).

:- pred cons(int,list(int),list(int)).
:- mode cons(in,in,out).
cons(H,T,[H|T]).

% =================================================================
% catamorphisms       
:- pred listmember(int,list(int),bool).
:- mode listmember(in,in,out).
:- cata listmember/3-2.

listmember(X,[],Res) :- constr(~Res).
listmember(X,[Y|Ys],B) :-
      constr( B=ite(X=Y,true,B1) ) ,
      listmember(X,Ys,B1).
  
         
% =================================================================
% Verification. 
% Property:
:- pred ff1.
ff1 :- 
   constr(~(SL=SS)), 
   listmember(X,L,SL), listmember(X,S,SS),  
   quicksort(L,S).

% contracts (postcondition: true)

:- spec partition(X,Ls,Smalls,Bigs) ==> listmember(Y,Ls,SLs), listmember(Y,Smalls,SSmalls), 
                                        listmember(Y,Bigs,SBigs).

:- spec append(Xs,Ys,Zs) ==> listmember(X,Xs,SXs), listmember(X,Ys,SYs), listmember(X,Zs,SZs).

:- spec cons(C,A,D) ==> listmember(X,A,SA), listmember(X,D,SD).

% =================================================================
:- query ff1/0.
% =================================================================