% =================================================================
:- pred constr(bool).    
:- mode constr(in).
:- ignore constr/1.

% =================================================================
% Program
:- pred quicksort(list(int),list(int)).
:- mode quicksort(in,out).
quicksort([], []).
quicksort([X | Xs], ResL) :-
	partition(X, Xs, Smalls, Bigs),   % partition of the tail Xs 
	quicksort(Smalls, Ls),            % with respect to the pivot X.
	quicksort(Bigs, Bs),              % X is NOT in Xs.
  cons(X,Bs,XBs),
	append(Ls, XBs, ResL).

:- pred partition(int,list(int),list(int),list(int)).
:- mode partition(in,in,out,out).
partition(X, [], [], []).
partition(X, [Y | Ys], [Y | Ls], Bs) :- 
      	constr( (X>Y) ),    
      	partition(X, Ys, Ls, Bs).
partition(X, [Y | Xs], Ls, [Y | Bs]) :-  
				constr( (X=<Y)  ),   
  			partition(X, Xs, Ls, Bs).

:- pred append(list(int),list(int),list(int)).
:- mode append(in,in,out).
append([],Ys,Ys).
append([X|Xs],Ys,[X|Zs]) :- append(Xs,Ys,Zs).

:- pred cons(int,list(int),list(int)).
:- mode cons(in,in,out).
cons(H,T,[H|T]).

% =================================================================
% catamorphisms       
%-----  listsum --- sum of integers in nodes of the given list.
:- pred listsum(list(int),int).
:- mode listsum(in,out).
:- cata listsum/2-1.

listsum([],S) :- S=0.
listsum([H|T],S) :-
  S=(H+ST),
  listsum(T,ST).
  
         
% =================================================================
% Verification. 
% Property:
:- pred ff1.
ff1 :- 
     constr( ~(LS=SS)), 
     listsum(L,LS),  
     listsum(S,SS), 
     quicksort(L,S).

% contracts (postcondition: true)

:- spec partition(X,Ls,Smalls,Bigs) ==> listsum(Ls,SLs), listsum(Smalls,SSmalls), 
                                        listsum(Bigs,SBigs).

:- spec append(Xs,Ys,Zs) ==> listsum(Xs,SXs), listsum(Ys,SYs), listsum(Zs,SZs).

:- spec cons(C,A,D) ==> listsum(A,SA), listsum(D,SD).

% =================================================================
:- query ff1/0.
% =================================================================