% =================================================================
:- pred constr(bool).    
:- mode constr(in).
:- ignore constr/1.

% =================================================================
% Program
:- pred quicksort(list(int),list(int)).
:- mode quicksort(in,out).
quicksort([], []).
quicksort([X | Xs], ResL) :-
	partition(X, Xs, Smalls, Bigs),   % partition of the tail Xs 
	quicksort(Smalls, Ls),            % with respect to the pivot X.
	quicksort(Bigs, Bs),              % X is NOT in Xs.
  concat(Ls,X,Bs,ResL).

:- pred partition(int,list(int),list(int),list(int)).
:- mode partition(in,in,out,out).
partition(X, [], [], []).
partition(X, [Y | Ys], [Y | Ls], Bs) :- 
      	constr( (X>Y) ),    
      	partition(X, Ys, Ls, Bs).
partition(X, [Y | Xs], Ls, [Y | Bs]) :-  
				constr( (X=<Y)  ),   
  			partition(X, Xs, Ls, Bs).

:- pred concat(list(int),int,list(int),list(int)).
:- mode concat(in,in,in,out).
concat([],X,Ys,[X|Ys]).
concat([X|Xs],Y,Ys,[X|Zs]) :-
	concat(Xs,Y,Ys,Zs).

% =================================================================
% catamorphism

:- pred length(list(int),int).
:- mode length(in,out).
:- cata length/2-1.

length([],L) :- constr((L=0)).
length([H|T],L) :-
  constr( (L=LT+1) ),
  length(T,LT).

% =================================================================
% Contract on quicksort:
:- spec quicksort(L,S) ==>
       length(L,LL), length(S,LS) =>
       constr((LL=LS)).

% Contract on partition:
:- spec partition(P,Ls,Smalls,Bigs) ==>
        length(Smalls,LSmalls), length(Bigs,LBigs), length(Ls,LLs)  =>
        constr( (LLs = (LSmalls+LBigs)) ).

% Contract on concat:
:- spec concat(Xs,Y,Ys,Zs) ==>
        length(Xs,LXs),  length(Ys,LYs), length(Zs,LZs)  =>
        constr( (LZs = (LXs+1+LYs)) ).

% =================================================================
% Verification. 
% Property:
:- pred ff1.
ff1 :- 
   constr(~(LL=LS)), 
   length(L,LL), length(S,LS),  
   quicksort(L,S).

:- pred ff2.
ff2 :- 
   constr( ~(LLs = (LSmalls+LBigs)) ), 
   length(Smalls,LSmalls), length(Bigs,LBigs), length(Ls,LLs), 
   partition(X,Ls,Smalls,Bigs).

:- pred ff3.
ff3 :- 
   constr( ~(LZs = (LXs+1+LYs)) ), 
   length(Xs,LXs), length(Ys,LYs), length(Zs,LZs), 
   concat(Xs,Y,Ys,Zs).

% =================================================================% NON-CATA predicates: concat constr partition quicksort